#version 3.7; 
#include "metals.inc"
#include "woods.inc"
#include "textures.inc"
#declare UseRad = 1;
#declare RandomSeed = seed(1);
#declare Photons = 1;
#declare ShowPlanet = 1;
#declare SunSphere = 1;
#declare Final = 1;
#declare Hei = 100*1000;
#declare Athm = 1750;
#declare Athm2 = Athm - 425;
#declare AthmS = 750;
#declare AthmMul = 4;
#declare AthmMul2 = 24;
#declare AthmMulS = 1;
#declare PlanetSize = 100000;
#declare LightMul = 1;
#declare ScatterCol = <0.25,0.375,1>;
#declare PanelAng = 15;
camera {
  sky <0,1,0>
	location <0,0,-4.000+PlanetSize+Hei>
	look_at 0
  angle 60
  up <0,9,0>
  right <16,0,0>
}

global_settings {
  #if (UseRad = 1)
  ambient_light rgb 0
  #else
  ambient_light rgb 0.5
  #end
	#if (Final = 1)
	max_trace_level 12
	#else
	max_trace_level 8
	#end
  charset utf8
  assumed_gamma 1
	#if (Photons = 1)
	photons {
    count 10000
		media 100
  }
	#end
}
#if (UseRad = 1)
#include "rad_def.inc"
global_settings {
   radiosity {
			#if (Final = 1)
			Rad_Settings(Radiosity_Final,off,off)
			recursion_limit 8
			#else
      Rad_Settings(Radiosity_Normal,off,off)
      recursion_limit 4
			#end
   }   
}
#default {finish{ambient 0}}
#end

background { color rgb 0 }
#declare D = .4; 
sky_sphere {
  pigment {
    crackle
    color_map {
      [ pow(0.5,D) color rgb 0 ] 
      [ pow(0.6,D) color rgb 1 ]
    }   
    scale .00125/D
  }
}


#declare Light =
union {
#if (SunSphere = 1)
sphere {
	<0,0,5*PlanetSize>,PlanetSize
	pigment {rgbt 1}
	interior {
		media {
		method 3
		emission rgb 1
		density {
			spherical
			turbulence 0.25
			scale PlanetSize 
			density_map {
				[0 rgb 0]
				[0.125 rgb <250,150,50> ]
				[0.25 rgb <350,250,150> ]
				[1 rgb 500]
			}
		}
		}
	}
	hollow
	no_shadow
}
#end
light_source {
  <0,0,5*PlanetSize>
  color rgb LightMul 
  parallel
  point_at <0,0,0>
  jitter
	media_attenuation on
	fade_power 2
	#if (Photons = 1)
  photons{
		reflection on
		refraction on
	}
	#end
}
};

#declare CloudsTex = 
texture {
  pigment {
     bozo 
     turbulence 0.65+1
     octaves 6
     omega 0.7
     lambda 2
     color_map {
       [0.0 0.175 color rgbt <1, 1, 1, 0.0> 
         color rgbt <1, 1, 1, 0.0>]
       [0.175 0.375 color rgbt <1, 1, 1, 0.0>
         color rgbt <1, 1, 1, 0.5>]
			 [0.375 0.625 color rgbt <1, 1, 1, 0.5>
				 color rgbt <1, 1, 1, 1.0>]
       [0.625 1.0 color rgbt <1, 1, 1, 1.0> 
         color rgbt <1, 1, 1, 1.0>]
     }    
 
    //scale 0.1
		scale 3750
		rotate <180*(1-2*rand(RandomSeed)),180*(1-2*rand(RandomSeed)),180*(1-2*rand(RandomSeed))>
  }
  finish {specular 0 diffuse 1 phong 0 emission 0.0 roughness 0.075 conserve_energy}
};

#declare SurMul = 1.25;
#declare SurfaceTex =
texture {
	pigment {
     bozo 
     turbulence 0.65 
     octaves 6
     omega 0.7
     lambda 2
     color_map {
       [0.0 0.2*SurMul color rgb <0.5,0.375,0.175> 
         color rgb <0.375,0.25,0>]
			 [0.2*SurMul 0.3*SurMul color rgb <0.375,0.25,0>
         color rgb <0.25,0.25,0.025>] 
       [0.3*SurMul 0.4*SurMul color rgb <0.175,0.275,0.025>
         color rgb <0.025,0.25,0.025>]
			 [0.4*SurMul 0.5*SurMul color rgb <0.075,0.25,0.5>*0.25
				 color rgb <0.0,0.0625,0.25>*0.05]
       [0.5*SurMul 1.0 color rgb <0.0,0.0625,0.25>*0.05
         color rgb <0.0,0.0,0.0625>*0]
     }    
		scale 5000*0.75
  }
  finish {phong 0 specular 0 diffuse 1 emission 0.0 roughness 0.075 conserve_energy}
};

#declare Planet =
union {
	sphere {
		0,PlanetSize/2
		texture {SurfaceTex}	
		texture {CloudsTex}
		hollow
		#if (Photons = 1)
		photons{
			target
			reflection on
			refraction on
		}
		#end
	}
	sphere {
		0,(PlanetSize+Athm)/2
		pigment {rgbt 1}
		hollow
		//no_shadow
		interior {
			media {
				method 3
				scattering { 4, ScatterCol}
				confidence 0.9999
				variance 0.0001
				density {
					spherical
					turbulence 0.000001
					scale (PlanetSize+Athm)/2
					density_map {
						[0 rgb 0]
						[(AthmS)/(PlanetSize+Athm) rgb AthmMulS/(PlanetSize/2)]
						[(Athm2)/(PlanetSize+Athm) rgb AthmMul/(PlanetSize/2)]
						[(Athm)/(PlanetSize+Athm) rgb AthmMul2/(PlanetSize/2)]	
						[1 rgb 0]
					}
				}
			}
			media {
				method 3
				absorption rgb <0.75,0.5,0.0>
				confidence 0.9999
				variance 0.0001
				density {
					spherical
					scale (PlanetSize+Athm)/2
					density_map {
						[0 rgb 0]
						[(AthmS)/(PlanetSize+Athm) rgb AthmMulS/(PlanetSize/2)]
						[(Athm2)/(PlanetSize+Athm) rgb AthmMul/(PlanetSize/2)]
						[(Athm)/(PlanetSize+Athm) rgb AthmMul2/(PlanetSize/2)]	
						[1 rgb 0]
					}
				}
			}
		}
		#if (Photons = 1)
		photons{
			//target
			pass_through
			reflection on
			refraction on
		}
		#end
	}
};
object {Light rotate <0,-54-60,0> translate (PlanetSize+Hei)*z}
#if (ShowPlanet = 1)
object {Planet}
#end